印刷ファイルの機能を拡張する

DDSの COLORキー・ワードを使うと印刷の文字カラーを指定することができますが
IBM i では COLORキー・ワードは *AFPDS でのみ有効と説明されています。
しかし z/OS ( IBM z ) では *SCS でもカラー属性が仕様として認められています。
Spoolライター提供の CRTEXPRTF コマンドでは COLORキー・ワードが
DDS ソースで指定された場合に印刷装置ファイル(*PRTF)に
*SCS IBM仕様に基づくカラー属性を生成します。
これによって生成された印刷装置ファイル(*PRTF)を使って RPG/COBOL などで
印刷出力すると *SCSストリームにはカラー属性が埋め込まれます。

*SCS カラー属性をサポートしているプリンターであればカラー印刷されますが
*SCS のカラー印刷をサポートしているSNAプリンターは少ないかも知れません。
しかし印刷スプールを CVTSPLFコマンドなどによって PDFに変換すれば
PDFには文字カラー属性が埋め込まれていますので、そのPDFを印刷できる
プリンターであればカラー文字を印刷することができることになります。

したがってSpoolライターのPDFドライバーやLPRドライバーによってPDF変換を
指定してPDF印刷可能なプリンターに送信してやると文字カラーを印刷することができます。

手元の「最寄りのプリンタ」に印刷出力するSpoolライターのローカル印刷の場合も
PCクライアントには PDFが送信されますのでそのクライアントに設定されている
プリンタがカラー印刷可能なプリンタであればカラー印刷することができます。

【例】

A                                    TKCODE      25
A                                                         COLOR(RED)

A                                    TKCODE     25
A                                                        COLOR(*RGB 255 255 255)

A                                     TKCODE   25
A                                                       COLOR(*CYMK)

カラー印刷の時代へ

0001.00 A**********************************
0002.00 A*  IGCLABELF :  漢字サンプル印刷 *
0003.00 A**********************************
0004.00 A*
0005.00 A*( 見出し行 )
0006.00 A          R COLPRT
0007.00 A                                      DFNLIN(*HRZ 2 2 40)
0008.00 A                                      DFNLIN(*HRZ 5 2 40)
0009.00 A                                  1  4' 漢字印刷サンプル '
0010.00 A                                      CHRSIZ(2)
0011.00 A                                  4 10'< カラー・サンプル >'
0012.00 A                                  7  3' 黒色 '
0013.00 A                                      COLOR(BLK)
0014.00 A                                  7 13' 青色 '
0015.00 A                                      COLOR(BLU)
0016.00 A                                  7 23' 茶色 '
0017.00 A                                      COLOR(BRN)
0018.00 A                                  7 33' 緑色 '
0019.00 A                                      COLOR(GRN)
0020.00 A                                  9  3' ピンク '
0021.00 A                                      COLOR(PNK)
0022.00 A                                  9 13' 赤色 '
0023.00 A                                      COLOR(RED)
0024.00 A                                  9 23' 空色 '
0025.00 A                                      COLOR(TRQ)
0026.00 A                                  9 33' 黄色 '
0027.00 A                                      COLOR(YLW)
0028.00 A*( 明細行 )
0029.00 A          R GIFPRT
0030.00 A                                      DFNLIN(*HRZ 11 2 40)
0031.00 A                                      DFNLIN(*HRZ 14 2 40)
0032.00 A                                 13 10'< 画像サンプル >'
0033.00 A                                 16  2' バイク '
0034.00 A                                 16 12IMAGE('/AS400-NET.USR/IMG/B
0035.00 A                                      JPG' 5 8)
0036.00 A                                 16 23' 電車 '
0037.00 A                                 16 33IMAGE('/AS400-NET.USR/IMG/R
0038.00 A                                      .JPG' 5 8)
0039.00 A                                 22  2' ライダー '
0040.00 A                                 22 12IMAGE(&P1 5 8)
0041.00 A            P1            32A  P
0042.00 A                                 22 23' 飛行機 '
0043.00 A                                 22 33IMAGE('/AS400-NET.USR/IMG/D
0044.00 A                                      JPG' 5 8)
0045.00 A*( 合計行 )
0046.00 A          R BOTPRT
0047.00 A*                                     BOX(4 12 10 32)
0048.00 A                                      DFNLIN(*HRZ  4 12 20)
0049.00 A                                      DFNLIN(*VRT  5 12 6)
0050.00 A                                      DFNLIN(*HRZ 10 12 20)
0051.00 A                                      DFNLIN(*VRT  5 32 6)

【作成】

CRTEXPRTF FILE(QTROBJ/IGCLABELF) SRCFILE(QTRSRC/QPRTSRC) LVLCHK(*NO) AUT(*ALL)

0001.00 H DFTNAME(IGCLABEL) DATEDIT(*YMD/)
0002.00 F**********  漢字サンプル印刷 *****************************************
0003.00 FTOKMAS    IF   E           K DISK
0004.00 FPRTF      O    E             PRINTER EXTDESC('QTROBJ/IGCLABELF')
0005.00 F                                     EXTFILE(*EXTDESC)
0006.00 F**********************************************************************
0007.00 D AR              S              1    DIM(80)
0008.00
0009.00 D*( WORK 日付 YYMMDD ﾃﾞｰﾀ 構造  )
0010.00 D DATEDS          DS
0011.00 D  SRY                    1      2  0 INZ(20)
0012.00 D  SRYMD                  1      8  0
0013.00 D  YYMMDD                 3      8  0
0014.00 D  YYMM                   3      6  0
0015.00 D  MMDD                   5      8  0
0016.00 D  YY                     3      4  0
0017.00 D  MM                     5      6  0
0018.00 D  DD                     7      8  0
0019.00
0020.00 D IFS             C                   CONST('/AS400-NET.USR/IMG/BKTTR7.
0021.00 D                                     JPG')
0022.00
0023.00 C                   SETOFF                                       99
0024.00 C     '0002'        CHAIN     TOKMAS                             99
0025.00 C*( カラー印刷 )
0026.00 C*----------------------------------------------------+
0027.00 C                   WRITE     COLPRT
0028.00 C*----------------------------------------------------+
0029.00 C*( 画像印刷 )
0030.00 C                   MOVEL(P)  IFS           P1
0031.00 C*----------------------------------------------------+
0032.00 C                   WRITE     GIFPRT
0033.00 C*----------------------------------------------------+
0034.00 C*( 底部印刷 )
0035.00 C*----------------------------------------------------+
0036.00 C*                  WRITE     BOTPRT
0037.00 C*----------------------------------------------------+
0038.00 C     END           TAG
0039.00 C                   SETON                                        LR
0040.00 C******************************************************
0041.00 C     *INZSR        BEGSR
0042.00 C******************************************************
0043.00 C*  初期 ｻｲｸﾙ のみの実行
0044.00 C                   MOVE      UDATE         YYMMDD
0045.00 C                   BITOFF    '06'          QUOT              1
0046.00 C                   BITON     '123457'      QUOT              1
0047.00 C                   ENDSR

【作成】

CRTBNDRPG PGM(SPOOLWTR/CRTEXPRTF) SRCFILE(R610SRC/QRPGLESRC) DFTACTGRP(*NO)
              ACTGRP(*NEW) DBGVIEW(*SOURCE) AUT(*ALL)

バーコードが占めることのできる最大の大きさを、行数・桁数で指定する。
バーコードの大きさは、この領域からはみ出さない範囲で最大の大きさとなるように、自動調整される。

省略可能。省略された場合は *R0 と見なされる。

バーコード化する際に、フィールド値末尾のブランク文字を除去するかどうかを指定します。

省略可能。省略された場合は *NOTRIM と見なされます。

バーコードの上または下に、人間の目で読める文字列を出力します。

省略可能。省略された場合は、文字列を出力しません。

※ QRコードを出力するには、追加オプションのご契約が必要です。

QRコードを生成するには、フィールド・レベルのキーワード BARCOD(QRCODE)を使用します。

BARCOD(QRCODE 高さ 幅 [トリム] [誤り訂正レベル])

このキーワードを指定したフィールドが、QRコードとして印字されます。

フィールドのデータ・タイプと桁数

高さ・幅

トリム

誤り訂正レベル

【サンプルDDS】

                  FLD1          24A     2  2BARCOD(QRCODE 6 10) 

                  FLD2        1000O       42BARCOD(QRCODE 6 18 *TRIM *EC3)

CODE128で使用可能な文字

OVERLAY('画像ファイルのパス' 下方向オフセット 横方向オフセット)

【例】OVERLAY('/SPOLWTR/DENPYO.JPG' 0 1.35)

OVERLAYキー・ワードの使用方法

OVERLAYキー・ワードはその印刷ファイル (PRTF) 内で最初に
出力される印刷レコードのみに記述してください。

OVERLAYキー・ワードは必ずレコード毎にフィールド記述の直前に
レコード・レベルとして記述してください。

OVERLAYキー・ワードは CRTEXPRTFコマンドの 前面オーバーレイ (FRONTOVL)
パラメータを指定するのと同じことになります。
前面オーバーレイ (FRONTOVL) を指定した場合も OVERLAYキー・ワードの
記述が最初の印刷レコードに挿入されます。
これに対して OVERLAYキー・ワードを使用することは手動で明示的に
DDS に OVERLAYキー・ワードを挿入することになります。

画像ファイルのパス

128バイト 以内で画像ファイルのフル・パス名を指定します。
画像ファイルは JPG または PNG 形式としてください。

画像が他の PC や PC サーバーに保管されているときは
QNTC 経由での表示を指定してください。
また他の PC や PC サーバーである場合、IBM i から参照するときには
必ず電源が ON になっている PC または PC サーバーに保管してください。
画像ファイルが保管されている PC に電源が入っていないと
QSYSOPR に警告メッセージが報告されます。

下方向オフセット

画像ファイルと印刷を重ね合わせるときに画像を下方向にずらす長さを
1/1000センチ (CM) 単位で指示します。( -57.790 〜 57.790 CM )
オフセット値は画像を印刷イメージより下の方向に移動させます。
このオフセット値はマイナス値も指定することができます。
マイナス値を指示することは画像を印刷イメージより上に移動することを意味しています。

横方向オフセット

画像ファイルと印刷を重ね合わせるときに画像を右方向にずらす長さを
1/1000センチ (CM) 単位で指示します。( -57.790 〜 57.790 CM )
オフセット値は画像を印刷イメージより右の方向に移動させます。
このオフセット値はマイナス値も指定することができます。
マイナス値を指示することは画像を印刷イメージより左に移動することを意味しています。

POSITION(行、桁)

フィールドの印刷位置を POSITION で指定した場所に移動して印刷します。
行、桁は小数点以下 2桁まで指定することができます。
行および桁はどちらも指定が必要です。
どちらかを省略することはできません。

【例】

       A       SURYO          9Y 0    13
       A                                POSITION(2.10 45.32)

【指定の方法】

DDS のフィールドとは別の行に新たに指定してください。

【誤った指定の方法】

       A       SHCODE        25A  O    85POSITION(6 145)

【正しい指定の方法】

       A       SHCODE        25A  O    85
       A                                            POSITION(6 145)

【相対位置の指定】

絶対位置の指定に対して、符号を数字の前に付加して記述すると
相対位置の指定と見なされて現在の位置に対する相対位置を
指定することができます。

       A         BHNCOD       14A  O     20
       A                                              POSITION(+10 -1)

POSITION キー・ワードはまた標識とともに指定することも可能です。

【例】

       A       SURYO          9Y 0    13
       A  42                          　　　 POSITION(2.10 45.32)

※ POSITION キー・ワードを指定すると SEU のエラーになる場合がありますが
    無視して上書きで保存してください。
※ POSITION キー・ワードを指定した場合は CRTPRTF ではなく
    必ず CRTEXPRTF コマンドによって印刷ファイル(PRTF)を作成してください。

CHRSIZ(比率)

または

CHRSIZ(横比率 縦比率)

の型式で、比率の夫々は小数桁 2位まで指定することができます。
CHRSIZ(比率) のように比率をひとつだけ指定した場合は
縦方向・横方向とも同じ比率で拡大または縮小が行われます。
CHRSIZ(横比率 縦比率)のようにどちらも指定すれば
横方向の比率と縦方向の比率をそれぞれ指定することができます。

【例】

       A            DLNAME        42O  O     6                          
       A                                      TEXT(' ディーラー名称 ')  
       A                                      CHRSIZ(1 2)               

【指定の方法】

DDSのフィールドとは別の行に新たに指定してください。

【誤った指定の方法】

       A       SHCODE        25A  O    85CHRSIZ(2.5)

【正しい指定の方法】

       A       SHCODE        25A  O    85
       A                                           CHRSIZ(2.5)

・POSITIONキー・ワードとの併用

POSITION キー・ワードと併用して指定することができますが
同じ行にまとめて記述するのではなくそれぞれ別の行に指定してください。

       A            COLOR         25A  O    85               
       A                                      TEXT(' 色 ')   
       A                                      POSITION(6 145)
       A                                      CHRSIZ(0.7)