国際言語化

国際言語を識別するためのコードが CCSID (=文字コード・セット: Coded Charactor Set ID) です。
例えば図書館に様々な本が保管されていたとしても、それが何語で書かれているのかを
わからなければ正しく読むことはできません。
例えば「汽車」という単語は日本語として解釈すれば「蒸気機関車」を意味しますが
中国語で解釈すれば「自動車」の意味になります。
「汽車」という単語が中国語であるのか日本語であるのかを識別するのが CCSID です。

コンピュータの中ではもっと複雑なので言語を識別するための文字コードが用意されています。
これが CCSID です。

【例】 CCSID の代表例

ユニコードとは

ユニコードとはすべての国際言語のコードを重複することなく表現するために
統一されたコードであり基本的には UTF-16 が最初に登場したユニコードであり
漢字は 3バイト で半角文字は 2バイト で表示されます。
しかしこれではかなり冗長となるため半角文字だけを今まで通りに 1バイト で
表現したのが UTF-8 というユニコードです。
今ではユニコードといえば殆ど UTF-8 が使用されていますが
ILE-RPG がサポートしているのは UTF-16 だけです。

CCSID 1399 はユニコードではない。

CCSID 1399 は 5035 + NEC 選定漢字がセットされたものです。
例えば「�梶vという字も CCSID 1399 には含まれています。
しかし 1399 はユニコードではありません。
ユニコードの CCSID は上図のように 1200 または 1208 (これ以外もありますが)です。
しかもユニコードの場合は漢字は 3バイト で表現されます。
CCSID 1399 にしたからといって EBCDIC 漢字が 3バイト になるわけではありません。
1399 がユニコードであるという、個人サイトや特約店 SE の説明は誤りです。

CTRL + F3 キーで CCSID は変化しない。

5250 エミュレータで CTRL + F3 キーを押すと CCSID が変化すると
説明している IBM 特約店があるようですが
CTRL + F3 キーでジョブの CCSID が変わることはありません。
5250 エミュレータのホスト・コードが変化するだけです。
CTRL + F3 キーで ジョブ属性が変化することはあり得ません。

  A                                  1 27' 部課マスターの登録

を次のようなメッセージ記述に書き換えます。

  A            TITLE_        20A  O  1 27MSGID(MSG0001 QTROBJ/USRMSG)

この記述によって DSPF は実行時にメッセージ・ファイル: QTROBJ/USRMSG の
MSGID: MSG0001 に記述されている文字列を表示します。
メッセージ・ファイル: QTROBJ/USRMSG は CCSID が日本語として
5026, 5035 または 1399 で登録されていますので日本語として表示されますが
中国語の CCSID:935 として登録されているメッセージ・ファイルであれば
中国語として変換されて表示されます。

日本語を始めとして国際言語のメッセージ・ファイルを 所定のライブラリーに作成します。

【例】 日本語メッセージ・ファイルの作成

CRTMSGF MSGF(MYLIB/JAPAN) TEXT(' 日本語メッセージ・ファイル ')
     AUT(*ALL) CCSID(5026)

【註】CCSID は 5026, 5035 または 1399 として作成します。

【例】 中国簡体字メッセージ・ファイルの作成

CRTMSGF MSGF(MYLIB/CHINA) TEXT(' 中国語メッセージ・ファイル ')
     AUT(*ALL) CCSID(935)

【註】中国簡体字: 935, 中国繁体字: 937, 韓国語: 833, 米国: 37

DSPF の DDS 記述の日本語の固定情報を MSGID 記述に変更します。

【例】

  A                                  2  2' 部課コード '

  A*                                 2  2' 部課コード '
  A            BUKA_         12A  O  2  2MSGID(MSG0002 QTROBJ/USRMSG)

ADDMSGD MSGID(MSG0002) MSGF(QTROBJ/USRMSG) MSG(' 部課コード ')

のようにして日本語メッセージ・ファイルを登録してください。

日本語環境で CRTDSPF コマンドを使って表示装置ファイル (DSPF) を
再作成してください。

該当の表示装置ファイル (DSPF) を使用している RPG/COBOL プログラムを
再コンパイルして実行します。
日本語環境下で MSGID に変更した日本語が正しく文字化けせずに
表示されているかを確認してください。

WRKLANG: 国際言語の登録 を使って国際言語を国際言語のメッセージ・ファイルに登録します。
詳細は 「WRKLANG: 国際言語の登録」を参照してください。
国際言語への翻訳は Google翻訳を使って行います。

OVRMSGF を使って国際語にオーバーライドして実行する CLP を作成してください。

【例】PGM119CL :USRMSG を中国語のメッセージ・ファイル:
         CHINALIB/USRMSG にオーバーライドさせて実行する。

0001.00              PGM
0002.00 /*---------------------------------------------------------*/
0003.00 /*    PGM119    :   部課マスターの登録 ( 中国語 )          */
0004.00 /*---------------------------------------------------------*/
0005.00              DCL        VAR(&MSG)      TYPE(*CHAR) LEN(80)
0006.00              MONMSG     MSGID(CPF0000) EXEC(GOTO CMDLBL(ERROR))
0007.00
0008.00              OVRMSGF    MSGF(USRMSG) TOMSGF(CHINALIB/USRMSG) +
0009.00                           SECURE(*YES)
0010.00              OVRDBF     FILE(BUKAM) TOFILE(QTRFIL/BUKAM) +
0011.00                           SECURE(*YES) OVRSCOPE(*JOB)
0012.00              CALL       QTROBJ/PGM119
0013.00              MONMSG     MSGID(RPG9801) EXEC(GOTO CMDLBL(ERROR))
0014.00              DLTOVR     FILE(BUKAM) LVL(*JOB)
0015.00              DLTOVR     FILE(USRMSG) LVL(*JOB)
0016.00              RETURN
0017.00
0018.00  ERROR:      RCVMSG     RMV(*NO) MSG(&MSG)
0019.00  SNDMSG:     SNDPGMMSG  MSG(&MSG) MSGTYPE(*DIAG)
0020.00              ENDPGM

【解説】

        OVRMSGF    MSGF(USRMSG) TOMSGF(CHINALIB/USRMSG) SECURE(*YES)

        CALL       QTROBJ/PGM119

        DLTOVR     FILE(USRMSG) LVL(*JOB)

8. AutoWeb で CLPを実行する。

作成した CLP を AutoWeb で動作させる最も簡単な方法は
CALL コマンドによって CLP を呼び出すのではなく
AutoWeb で提供されている CALLWEB コマンドを使うことです。

【例】CALLWEB QTROBJ/PGM119CL

【解説】

表題や欄見出しのような固定情報は中国語として
表示されていますがデータ・ベースは日本語のままで
文字化けせずに表示されていることに着目してください。
これは日本語環境のままで実行されているからです。

CALLWEB コマンドとは

CALLWEB コマンドとは CALL コマンドと動作は同じで
プログラムをパラメータつきで呼び出して実行する
コマンドですが CALL コマンドは 5250 エミュレータ上で
実行しますが CALLWEB コマンドは AutoWeb 上で実行されます。

CALLWEB は呼び出された時点で次の環境を AutoWeb に継承して実行します。

• ユーザー・プロフィール 　　　　　　
• パラメータ
• ライブラリー・リスト
• *LDA
• 省略時の CCSID

右上には言語選択のための静的なコンボボックスが表示されています。
これは DDS では

　A            LANG           3A  B  5 67
　A                                      VALUES('JPN' 'CHN')
　A                                      TEXT('" 日本語 " " 中国語 " *SBM')

のように定義されています。
TEXT キー・ワードの最後の「*SBM」は、このコンボボックスの選択と同時に
SUBMIT されることを意味しています。
すなわちコンボボックスを選択すると自動的に実行キー (ENTER) を押したのと
同じになります。

制御が RPG に戻ると RPG は選択に応じて次のようなサブ・ルーチンを実行します。

H DFTNAME(PGM109) DATEDIT(*YMD/) BNDDIR('QC2LE')
  :
D SYSTEM          PR            10I 0 EXTPROC('system')
D   PATH                          *   VALUE OPTIONS(*STRING)
  :
C******************************************************
C     CHINA_        BEGSR
C******************************************************
  *( 中国語 )
  /FREE
    SYSTEM('OVRMSGF MSGF(USRMSG) TOMSGF(CHINALIB/USRMSG) SECURE(*YES)');
    FLGIMG = BEGIMG + CHINA + ENDIMG;
  /END-FREE
C                   ENDSR
C******************************************************
C     JAPAN_        BEGSR
C******************************************************
  *( 日本語 )
  /FREE
    SYSTEM('DLTOVR FILE(USRMSG) LVL(*)');
    FLGIMG = BEGIMG + JAPAN + ENDIMG;
  /END-FREE
C                   ENDSR

【解説】

SYSTEM 関数とは QCMDEXC と同じ機能でありコマンドを実行する C 言語の関数です。
QCMDEXC を使うより SYSTEM 関数のほうが直感的で見やすくわかりやすい
コマンド実行を記述することができます。
H-仕様書に BNDDIR('QC2LE') と記述しておけばコンパイラーによって
C 言語の関数を参照することができるようになります。

【 DSPF      : PGM109FMソース 】   

【 ILE-RPG : PGM109ソース      】   

データ・ベースを始めとしてすべての変数、つまりフィールドが
同一の言語である場合は、実行ジョブの CCSID は 65535,
国コードを言語コードに設定します。

【例】中国語環境に設定

CHGJOB LANGID(CHS) CNTRYID(CN) CCSID(65535)

国コードが CHS であるので省略時の CCSID は i5/OS によって 935 に
設定されます。( DFTCCSID )
これによってすべて中国語による表示と入力も行うことができます。
データ・ベースやフィールド値はすべて中国語: CCSID 935 であると
解釈されて Web サイトの UTF-8 の文字コードに変換されます。
また入力した文字列も IBM i 内部では中国語: 935 に変換されて保管されます。

  A            MSGENG        48O  B  8 64TEXT('*CCSID 935')

TEXTキー・ワードの最初の桁から *CCSID xxxx のようにして
フィールド個別の CCSID を指定することができます。
これによってこのフィールドは指定した CCSID 値から UTF-8 への
翻訳が行われ、入力時にはその逆の翻訳がなされます。

表示のときは *CCSID によるフィールド個別の CCSID 指定による複数の
言語の同時表示は可能ですが入力のときはひとつの言語に限られており
同時に複数の言語を入力することはできません。
これは AutoWeb が HTMLインターフェースである文字コード:UTF-8 から
IBM i への文字コードへの変換はジョブの(ただひとつの)
省略時の文字コードへ変換されるからです。
そのジョブ環境は例えば中国語であれば

CHGJOB LANGID(CHS) CNTRYID(CN) CCSID(65535)

のようにして設定しておかねばなりません。
CCSID の値は必ず 65535 に設定してください。
動的に他の言語の入力も可能にしたいのであれば

CHGJOB LANGID(JPN) CNTRYID(JP) CCSID(65535)

などのコマンドをプログラム内部で実行できるように
しなければなりません。
この設定はプログラマーの責任の範囲内において
設定しなければなりません。

下記は日本語と中国語の入力を「F11=切替」によって切替えて
入力できる高度な事例となる「WRKLANG:国際言語の登録」を示しています。

サンプル : WRKLANG : 国際言語の登録

この適用業務のくわしい使用方法はこちらで

このプログラムは「F11=切替」で日本語の入力モードと中国語の入力モードの どちらかに切替えることができます。 内部では日本語の入力モードの開始が選択されると

CHGJOB LANGID(JPN) CNTRYID(JP) CCSID(65535)

のコマンドが実行され、中国語の入力モードが選択されると

CHGJOB LANGID(CHS) CNTRYID(CN) CCSID(65535)

が実行されるようになっています。